initial k3s on MicroOS on Hetzner ok

servers.tf

@@ -0,0 +1,95 @@
+resource "hcloud_server" "control_planes" {
+  count = var.servers_num - 1
+  name  = "k3s-control-plane-${count.index + 1}"
+
+  image              = data.hcloud_image.linux.name
+  rescue             = "linux64"
+  server_type        = var.control_plane_server_type
+  location           = var.location
+  ssh_keys           = [hcloud_ssh_key.k3s.id]
+  firewall_ids       = [hcloud_firewall.k3s.id]
+  placement_group_id = hcloud_placement_group.k3s_placement_group.id
+
+  labels = {
+    "provisioner" = "terraform",
+    "engine"      = "k3s",
+  }
+
+  provisioner "file" {
+    content = templatefile("${path.module}/templates/config.ign.tpl", {
+      name           = self.name
+      ssh_public_key = local.ssh_public_key
+    })
+    destination = "/root/config.ign"
+
+    connection {
+      user           = "root"
+      private_key    = local.ssh_private_key
+      agent_identity = local.ssh_identity
+      host           = self.ipv4_address
+    }
+  }
+
+  # Install MicroOS
+  provisioner "remote-exec" {
+    inline = local.MicroOS_install_commands
+
+    connection {
+      user           = "root"
+      private_key    = local.ssh_private_key
+      agent_identity = local.ssh_identity
+      host           = self.ipv4_address
+    }
+  }
+
+  # Wait for MicroOS to reboot and be ready
+  provisioner "local-exec" {
+    command = "sleep 60 && ping ${self.ipv4_address} | grep --line-buffered 'bytes from' | head -1 && sleep 30"
+  }
+
+  # Generating k3s server config file
+  provisioner "file" {
+    content = templatefile("${path.module}/templates/server_config.yaml.tpl", {
+      first_control_plane_url = "https://${local.first_control_plane_network_ip}:6443"
+      node_ip                 = cidrhost(hcloud_network.k3s.ip_range, 3 + count.index)
+      token                   = random_password.k3s_token.result
+      node_name               = self.name
+    })
+    destination = "/etc/rancher/k3s/config.yaml"
+
+    connection {
+      user           = "root"
+      private_key    = local.ssh_private_key
+      agent_identity = local.ssh_identity
+      host           = self.ipv4_address
+    }
+  }
+
+  # Run the other control plane
+  provisioner "remote-exec" {
+    inline = [
+      "set -ex",
+      # first we disable automatic reboot (after transactional updates), and configure the reboot method as kured
+      "rebootmgrctl set-strategy off && echo 'REBOOT_METHOD=kured' > /etc/transactional-update.conf",
+      # then we initiate the cluster
+      "systemctl --now enable k3s-server",
+    ]
+
+    connection {
+      user           = "root"
+      private_key    = local.ssh_private_key
+      agent_identity = local.ssh_identity
+      host           = self.ipv4_address
+    }
+  }
+
+  network {
+    network_id = hcloud_network.k3s.id
+    ip         = cidrhost(hcloud_network.k3s.ip_range, 3 + count.index)
+  }
+
+  depends_on = [
+    hcloud_server.first_control_plane,
+    hcloud_network_subnet.k3s
+  ]
+}