Europa docs: From local dev to CI environment doc page

The todoapp example contains a Netlify plan which uses the latest dagger
additions: do & Client API. We are thinking of merging the examples
repository into this one to make working with this easier. This is a
step in that direction.

We are not using the yarn package so that we can revert
https://github.com/dagger/dagger/pull/1673 without breaking this
implementation.

The GitHub Action is WIP, we will continue with that tomorrow:
https://github.com/dagger/dagger-for-github/issues/24

Signed-off-by: Gerhard Lazu <gerhard@lazu.co.uk>

pkg/universe.dagger.io/examples/todoapp/netlify.cue

@@ -0,0 +1,94 @@
+package netlify
+
+import (
+	"dagger.io/dagger"
+	"universe.dagger.io/alpine"
+	"universe.dagger.io/bash"
+	"universe.dagger.io/docker"
+	"universe.dagger.io/netlify"
+)
+
+dagger.#Plan & {
+	client: {
+		filesystem: {
+			".": read: {
+				contents: dagger.#FS
+				exclude: [
+					"README.md",
+					"build",
+					"netlify.cue",
+					"node_modules",
+				]
+			}
+			build: write: contents: actions.build.contents.output
+		}
+		env: {
+			APP_NAME:      string
+			NETLIFY_TEAM:  string
+			NETLIFY_TOKEN: dagger.#Secret
+		}
+	}
+	actions: {
+		deps: docker.#Build & {
+			steps: [
+				alpine.#Build & {
+					packages: {
+						bash: {}
+						yarn: {}
+						git: {}
+					}
+				},
+				docker.#Copy & {
+					contents: client.filesystem.".".read.contents
+					dest:     "/src"
+				},
+				// bash.#Run is a superset of docker.#Run
+				// install yarn dependencies
+				bash.#Run & {
+					workdir: "/src"
+					mounts: "/cache/yarn": dagger.#Mount & {
+						dest:     "/cache/yarn"
+						type:     "cache"
+						contents: dagger.#CacheDir & {
+							id: "todoapp-yarn-cache"
+						}
+					}
+					script: contents: #"""
+						yarn config set cache-folder /cache/yarn
+						yarn install
+						"""#
+				},
+			]
+		}
+
+		test: bash.#Run & {
+			input:   deps.output
+			workdir: "/src"
+			script: contents: #"""
+				yarn run test
+				"""#
+		}
+
+		build: {
+			run: bash.#Run & {
+				input:   test.output
+				workdir: "/src"
+				script: contents: #"""
+					yarn run build
+					"""#
+			}
+
+			contents: dagger.#Subdir & {
+				input: run.output.rootfs
+				path:  "/src/build"
+			}
+		}
+
+		deploy: netlify.#Deploy & {
+			contents: build.contents.output
+			site:     client.env.APP_NAME
+			token:    client.env.NETLIFY_TOKEN
+			team:     client.env.NETLIFY_TEAM
+		}
+	}
+}