Revise Europa Docs - Core Concepts - It all starts with a plan

Thank you Tanguy for the "fresh pair of eyes" perspective.

Thank you Tom for the link suggestions.

Supersedes https://github.com/dagger/dagger/pull/1847

Signed-off-by: Gerhard Lazu <gerhard@lazu.co.uk>

pkg/universe.dagger.io/examples/todoapp/todoapp.cue

@@ -0,0 +1,105 @@
+package todoapp
+
+import (
+	"dagger.io/dagger"
+	"universe.dagger.io/alpine"
+	"universe.dagger.io/bash"
+	"universe.dagger.io/docker"
+	"universe.dagger.io/netlify"
+)
+
+dagger.#Plan & {
+	_nodeModulesMount: "/src/node_modules": dagger.#Mount & {
+		dest:     "/src/node_modules"
+		type:     "cache"
+		contents: dagger.#CacheDir & {
+			id: "todoapp-modules-cache"
+		}
+
+	}
+	client: {
+		filesystem: {
+			".": read: {
+				contents: dagger.#FS
+				exclude: [
+					"README.md",
+					"_build",
+					"todoapp.cue",
+					"node_modules",
+				]
+			}
+			"./_build": write: contents: actions.build.contents.output
+		}
+		env: {
+			APP_NAME:      string
+			NETLIFY_TEAM:  string
+			NETLIFY_TOKEN: dagger.#Secret
+		}
+	}
+	actions: {
+		deps: docker.#Build & {
+			steps: [
+				alpine.#Build & {
+					packages: {
+						bash: {}
+						yarn: {}
+						git: {}
+					}
+				},
+				docker.#Copy & {
+					contents: client.filesystem.".".read.contents
+					dest:     "/src"
+				},
+				bash.#Run & {
+					workdir: "/src"
+					mounts: {
+						"/cache/yarn": dagger.#Mount & {
+							dest:     "/cache/yarn"
+							type:     "cache"
+							contents: dagger.#CacheDir & {
+								id: "todoapp-yarn-cache"
+							}
+						}
+						_nodeModulesMount
+					}
+					script: contents: #"""
+						yarn config set cache-folder /cache/yarn
+						yarn install
+						"""#
+				},
+			]
+		}
+
+		test: bash.#Run & {
+			input:   deps.output
+			workdir: "/src"
+			mounts:  _nodeModulesMount
+			script: contents: #"""
+				yarn run test
+				"""#
+		}
+
+		build: {
+			run: bash.#Run & {
+				input:   test.output
+				mounts:  _nodeModulesMount
+				workdir: "/src"
+				script: contents: #"""
+					yarn run build
+					"""#
+			}
+
+			contents: dagger.#Subdir & {
+				input: run.output.rootfs
+				path:  "/src/build"
+			}
+		}
+
+		deploy: netlify.#Deploy & {
+			contents: build.contents.output
+			site:     client.env.APP_NAME
+			token:    client.env.NETLIFY_TOKEN
+			team:     client.env.NETLIFY_TEAM
+		}
+	}
+}