cue modules: move stdlib to pkg/alpha.dagger.io

In preparation for Europa, we will vendor multiple CUE modules:

- `pkg/alpha.dagger.io`: legacy non-europa packages
- `pkg/dagger.io`: core Europa packages
- `pkg/universe.dagger.io`: Europa universe

Signed-off-by: Andrea Luzzardi <aluzzardi@gmail.com>

pkg/alpha.dagger.io/kubernetes/helm/code.cue

@@ -0,0 +1,43 @@
+package helm
+
+#code: #"""
+	# Add the repository
+	if [ -n "$HELM_REPO" ]; then
+		helm repo add repository "${HELM_REPO}"
+		helm repo update
+	fi
+
+	# If the chart is a file, then it's the chart name
+	# If it's a directly, then it's the contents of the cart
+	if [ -f "/helm/chart" ]; then
+	    HELM_CHART="repository/$(cat /helm/chart)"
+	else
+	    HELM_CHART="/helm/chart"
+	fi
+
+	OPTS=""
+	OPTS="$OPTS --timeout "$HELM_TIMEOUT""
+	OPTS="$OPTS --namespace "$KUBE_NAMESPACE""
+	[ "$HELM_WAIT" = "true" ] && OPTS="$OPTS --wait"
+	[ "$HELM_ATOMIC" = "true" ] && OPTS="$OPTS --atomic"
+	[ -f "/helm/values.yaml" ] && OPTS="$OPTS -f /helm/values.yaml"
+
+	# Select the namespace
+	kubectl create namespace "$KUBE_NAMESPACE" || true
+
+	case "$HELM_ACTION" in
+	    install)
+	        helm install $OPTS "$HELM_NAME" "$HELM_CHART"
+	    ;;
+	    upgrade)
+	        helm upgrade $OPTS "$HELM_NAME" "$HELM_CHART"
+	    ;;
+	    installOrUpgrade)
+	        helm upgrade $OPTS --install "$HELM_NAME" "$HELM_CHART"
+	    ;;
+	    *)
+	        echo unsupported helm action "$HELM_ACTION"
+	        exit 1
+	    ;;
+	esac
+	"""#

pkg/alpha.dagger.io/kubernetes/helm/helm.cue

@@ -0,0 +1,143 @@
+// Helm package manager
+package helm
+
+import (
+	"strconv"
+
+	"alpha.dagger.io/dagger"
+	"alpha.dagger.io/dagger/op"
+	"alpha.dagger.io/kubernetes"
+)
+
+// Install a Helm chart
+#Chart: {
+
+	// Helm deployment name
+	name: dagger.#Input & {string}
+
+	// Helm chart to install from source
+	chartSource: *null | dagger.#Artifact
+
+	// Helm chart to install from repository
+	chart: dagger.#Input & {*null | string}
+
+	// Helm chart repository
+	repository: dagger.#Input & {*null | string}
+
+	// Helm values (either a YAML string or a Cue structure)
+	values: dagger.#Input & {*null | string}
+
+	// Kubernetes Namespace to deploy to
+	namespace: dagger.#Input & {string}
+
+	// Helm action to apply
+	action: dagger.#Input & {*"installOrUpgrade" | "install" | "upgrade"}
+
+	// time to wait for any individual Kubernetes operation (like Jobs for hooks)
+	timeout: dagger.#Input & {string | *"5m"}
+
+	// if set, will wait until all Pods, PVCs, Services, and minimum number of
+	// Pods of a Deployment, StatefulSet, or ReplicaSet are in a ready state
+	// before marking the release as successful.
+	// It will wait for as long as timeout
+	wait: dagger.#Input & {*true | bool}
+
+	// if set, installation process purges chart on fail.
+	// The wait option will be set automatically if atomic is used
+	atomic: dagger.#Input & {*true | bool}
+
+	// Kube config file
+	kubeconfig: dagger.#Input & {string | dagger.#Secret}
+
+	// Helm version
+	version: dagger.#Input & {*"3.5.2" | string}
+
+	// Kubectl version
+	kubectlVersion: dagger.#Input & {*"v1.19.9" | string}
+
+	#up: [
+		op.#Load & {
+			from: kubernetes.#Kubectl & {
+				version: kubectlVersion
+			}
+		},
+		op.#Exec & {
+			env: HELM_VERSION: version
+			args: [
+				"/bin/bash",
+				"--noprofile",
+				"--norc",
+				"-eo",
+				"pipefail",
+				"-c",
+				#"""
+					# Install Yarn
+					curl -sfL -S https://get.helm.sh/helm-v${HELM_VERSION}-linux-amd64.tar.gz | \
+					    tar -zx -C /tmp && \
+					    mv /tmp/linux-amd64/helm /usr/local/bin && \
+					    chmod +x /usr/local/bin/helm
+					"""#,
+			]
+		},
+		op.#Mkdir & {
+			path: "/helm"
+		},
+		op.#WriteFile & {
+			dest:    "/entrypoint.sh"
+			content: #code
+		},
+
+		if (kubeconfig & string) != _|_ {
+			op.#WriteFile & {
+				dest:    "/kubeconfig"
+				content: kubeconfig
+				mode:    0o600
+			}
+		},
+
+		if chart != null {
+			op.#WriteFile & {
+				dest:    "/helm/chart"
+				content: chart
+			}
+		},
+		if values != null {
+			op.#WriteFile & {
+				dest:    "/helm/values.yaml"
+				content: values
+			}
+		},
+		op.#Exec & {
+			always: true
+			args: [
+				"/bin/bash",
+				"--noprofile",
+				"--norc",
+				"-eo",
+				"pipefail",
+				"/entrypoint.sh",
+			]
+			env: {
+				KUBECONFIG:     "/kubeconfig"
+				KUBE_NAMESPACE: namespace
+
+				if repository != null {
+					HELM_REPO: repository
+				}
+				HELM_NAME:    name
+				HELM_ACTION:  action
+				HELM_TIMEOUT: timeout
+				HELM_WAIT:    strconv.FormatBool(wait)
+				HELM_ATOMIC:  strconv.FormatBool(atomic)
+			}
+			mount: {
+				if chartSource != null && chart == null {
+					"/helm/chart": from: chartSource
+				}
+				if (kubeconfig & dagger.#Secret) != _|_ {
+					"/kubeconfig": secret: kubeconfig
+				}
+			}
+		},
+	]
+}

pkg/alpha.dagger.io/kubernetes/helm/tests/helm.cue

@@ -0,0 +1,57 @@
+package helm
+
+import (
+	"alpha.dagger.io/random"
+	"alpha.dagger.io/dagger"
+)
+
+// We assume that a kinD cluster is running locally
+// To deploy a local KinD cluster, follow this link : https://kind.sigs.k8s.io/docs/user/quick-start/
+TestKubeconfig: dagger.#Input & {string}
+
+TestChartSource: dagger.#Input & {dagger.#Artifact}
+
+// Deploy user local chart
+TestHelmSimpleChart: {
+	suffix: random.#String & {
+		seed:   "simple"
+		length: 5
+	}
+
+	// Deploy chart
+	deploy: #Chart & {
+		name:        "dagger-test-inline-\(suffix.out)"
+		namespace:   "dagger-test"
+		kubeconfig:  TestKubeconfig
+		chartSource: TestChartSource
+	}
+
+	// Verify deployment
+	verify: #VerifyHelm & {
+		chartName: deploy.name
+		namespace: deploy.namespace
+	}
+}
+
+// Deploy remote chart
+TestHelmRepoChart: {
+	suffix: random.#String & {
+		seed:   "repo"
+		length: 5
+	}
+
+	// Deploy remote chart
+	deploy: #Chart & {
+		name:       "dagger-test-repository-\(suffix.out)"
+		namespace:  "dagger-test"
+		kubeconfig: TestKubeconfig
+		repository: "https://charts.bitnami.com/bitnami"
+		chart:      "redis"
+	}
+
+	// Verify deployment
+	verify: #VerifyHelm & {
+		chartName: deploy.name
+		namespace: deploy.namespace
+	}
+}

pkg/alpha.dagger.io/kubernetes/helm/tests/testdata/mychart/.helmignore

@@ -0,0 +1,23 @@
+# Patterns to ignore when building packages.
+# This supports shell glob matching, relative path matching, and
+# negation (prefixed with !). Only one pattern per line.
+.DS_Store
+# Common VCS dirs
+.git/
+.gitignore
+.bzr/
+.bzrignore
+.hg/
+.hgignore
+.svn/
+# Common backup files
+*.swp
+*.bak
+*.tmp
+*.orig
+*~
+# Various IDEs
+.project
+.idea/
+*.tmproj
+.vscode/

pkg/alpha.dagger.io/kubernetes/helm/tests/testdata/mychart/Chart.yaml

@@ -0,0 +1,21 @@
+apiVersion: v2
+name: mychart
+description: A Helm chart for Kubernetes
+
+# A chart can be either an 'application' or a 'library' chart.
+#
+# Application charts are a collection of templates that can be packaged into versioned archives
+# to be deployed.
+#
+# Library charts provide useful utilities or functions for the chart developer. They're included as
+# a dependency of application charts to inject those utilities and functions into the rendering
+# pipeline. Library charts do not define any templates and therefore cannot be deployed.
+type: application
+
+# This is the chart version. This version number should be incremented each time you make changes
+# to the chart and its templates, including the app version.
+version: 0.1.0
+
+# This is the version number of the application being deployed. This version number should be
+# incremented each time you make changes to the application.
+appVersion: 1.16.0

pkg/alpha.dagger.io/kubernetes/helm/tests/testdata/mychart/templates/NOTES.txt

@@ -0,0 +1,21 @@
+1. Get the application URL by running these commands:
+{{- if .Values.ingress.enabled }}
+{{- range $host := .Values.ingress.hosts }}
+  {{- range .paths }}
+  http{{ if $.Values.ingress.tls }}s{{ end }}://{{ $host.host }}{{ . }}
+  {{- end }}
+{{- end }}
+{{- else if contains "NodePort" .Values.service.type }}
+  export NODE_PORT=$(kubectl get --namespace {{ .Release.Namespace }} -o jsonpath="{.spec.ports[0].nodePort}" services {{ include "mychart.fullname" . }})
+  export NODE_IP=$(kubectl get nodes --namespace {{ .Release.Namespace }} -o jsonpath="{.items[0].status.addresses[0].address}")
+  echo http://$NODE_IP:$NODE_PORT
+{{- else if contains "LoadBalancer" .Values.service.type }}
+     NOTE: It may take a few minutes for the LoadBalancer IP to be available.
+           You can watch the status of by running 'kubectl get --namespace {{ .Release.Namespace }} svc -w {{ include "mychart.fullname" . }}'
+  export SERVICE_IP=$(kubectl get svc --namespace {{ .Release.Namespace }} {{ include "mychart.fullname" . }} --template "{{"{{ range (index .status.loadBalancer.ingress 0) }}{{.}}{{ end }}"}}")
+  echo http://$SERVICE_IP:{{ .Values.service.port }}
+{{- else if contains "ClusterIP" .Values.service.type }}
+  export POD_NAME=$(kubectl get pods --namespace {{ .Release.Namespace }} -l "app.kubernetes.io/name={{ include "mychart.name" . }},app.kubernetes.io/instance={{ .Release.Name }}" -o jsonpath="{.items[0].metadata.name}")
+  echo "Visit http://127.0.0.1:8080 to use your application"
+  kubectl --namespace {{ .Release.Namespace }} port-forward $POD_NAME 8080:80
+{{- end }}

pkg/alpha.dagger.io/kubernetes/helm/tests/testdata/mychart/templates/_helpers.tpl

@@ -0,0 +1,63 @@
+{{/* vim: set filetype=mustache: */}}
+{{/*
+Expand the name of the chart.
+*/}}
+{{- define "mychart.name" -}}
+{{- default .Chart.Name .Values.nameOverride | trunc 63 | trimSuffix "-" -}}
+{{- end -}}
+
+{{/*
+Create a default fully qualified app name.
+We truncate at 63 chars because some Kubernetes name fields are limited to this (by the DNS naming spec).
+If release name contains chart name it will be used as a full name.
+*/}}
+{{- define "mychart.fullname" -}}
+{{- if .Values.fullnameOverride -}}
+{{- .Values.fullnameOverride | trunc 63 | trimSuffix "-" -}}
+{{- else -}}
+{{- $name := default .Chart.Name .Values.nameOverride -}}
+{{- if contains $name .Release.Name -}}
+{{- .Release.Name | trunc 63 | trimSuffix "-" -}}
+{{- else -}}
+{{- printf "%s-%s" .Release.Name $name | trunc 63 | trimSuffix "-" -}}
+{{- end -}}
+{{- end -}}
+{{- end -}}
+
+{{/*
+Create chart name and version as used by the chart label.
+*/}}
+{{- define "mychart.chart" -}}
+{{- printf "%s-%s" .Chart.Name .Chart.Version | replace "+" "_" | trunc 63 | trimSuffix "-" -}}
+{{- end -}}
+
+{{/*
+Common labels
+*/}}
+{{- define "mychart.labels" -}}
+helm.sh/chart: {{ include "mychart.chart" . }}
+{{ include "mychart.selectorLabels" . }}
+{{- if .Chart.AppVersion }}
+app.kubernetes.io/version: {{ .Chart.AppVersion | quote }}
+{{- end }}
+app.kubernetes.io/managed-by: {{ .Release.Service }}
+{{- end -}}
+
+{{/*
+Selector labels
+*/}}
+{{- define "mychart.selectorLabels" -}}
+app.kubernetes.io/name: {{ include "mychart.name" . }}
+app.kubernetes.io/instance: {{ .Release.Name }}
+{{- end -}}
+
+{{/*
+Create the name of the service account to use
+*/}}
+{{- define "mychart.serviceAccountName" -}}
+{{- if .Values.serviceAccount.create -}}
+    {{ default (include "mychart.fullname" .) .Values.serviceAccount.name }}
+{{- else -}}
+    {{ default "default" .Values.serviceAccount.name }}
+{{- end -}}
+{{- end -}}

pkg/alpha.dagger.io/kubernetes/helm/tests/testdata/mychart/templates/deployment.yaml

@@ -0,0 +1,55 @@
+apiVersion: apps/v1
+kind: Deployment
+metadata:
+  name: {{ include "mychart.fullname" . }}
+  labels:
+    {{- include "mychart.labels" . | nindent 4 }}
+spec:
+  replicas: {{ .Values.replicaCount }}
+  selector:
+    matchLabels:
+      {{- include "mychart.selectorLabels" . | nindent 6 }}
+  template:
+    metadata:
+      labels:
+        {{- include "mychart.selectorLabels" . | nindent 8 }}
+    spec:
+    {{- with .Values.imagePullSecrets }}
+      imagePullSecrets:
+        {{- toYaml . | nindent 8 }}
+    {{- end }}
+      serviceAccountName: {{ include "mychart.serviceAccountName" . }}
+      securityContext:
+        {{- toYaml .Values.podSecurityContext | nindent 8 }}
+      containers:
+        - name: {{ .Chart.Name }}
+          securityContext:
+            {{- toYaml .Values.securityContext | nindent 12 }}
+          image: "{{ .Values.image.repository }}:{{ .Chart.AppVersion }}"
+          imagePullPolicy: {{ .Values.image.pullPolicy }}
+          ports:
+            - name: http
+              containerPort: 80
+              protocol: TCP
+          livenessProbe:
+            httpGet:
+              path: /
+              port: http
+          readinessProbe:
+            httpGet:
+              path: /
+              port: http
+          resources:
+            {{- toYaml .Values.resources | nindent 12 }}
+      {{- with .Values.nodeSelector }}
+      nodeSelector:
+        {{- toYaml . | nindent 8 }}
+      {{- end }}
+    {{- with .Values.affinity }}
+      affinity:
+        {{- toYaml . | nindent 8 }}
+    {{- end }}
+    {{- with .Values.tolerations }}
+      tolerations:
+        {{- toYaml . | nindent 8 }}
+    {{- end }}

pkg/alpha.dagger.io/kubernetes/helm/tests/testdata/mychart/templates/ingress.yaml

@@ -0,0 +1,41 @@
+{{- if .Values.ingress.enabled -}}
+{{- $fullName := include "mychart.fullname" . -}}
+{{- $svcPort := .Values.service.port -}}
+{{- if semverCompare ">=1.14-0" .Capabilities.KubeVersion.GitVersion -}}
+apiVersion: networking.k8s.io/v1beta1
+{{- else -}}
+apiVersion: extensions/v1beta1
+{{- end }}
+kind: Ingress
+metadata:
+  name: {{ $fullName }}
+  labels:
+    {{- include "mychart.labels" . | nindent 4 }}
+  {{- with .Values.ingress.annotations }}
+  annotations:
+    {{- toYaml . | nindent 4 }}
+  {{- end }}
+spec:
+{{- if .Values.ingress.tls }}
+  tls:
+  {{- range .Values.ingress.tls }}
+    - hosts:
+      {{- range .hosts }}
+        - {{ . | quote }}
+      {{- end }}
+      secretName: {{ .secretName }}
+  {{- end }}
+{{- end }}
+  rules:
+  {{- range .Values.ingress.hosts }}
+    - host: {{ .host | quote }}
+      http:
+        paths:
+        {{- range .paths }}
+          - path: {{ . }}
+            backend:
+              serviceName: {{ $fullName }}
+              servicePort: {{ $svcPort }}
+        {{- end }}
+  {{- end }}
+{{- end }}

pkg/alpha.dagger.io/kubernetes/helm/tests/testdata/mychart/templates/service.yaml

@@ -0,0 +1,15 @@
+apiVersion: v1
+kind: Service
+metadata:
+  name: {{ include "mychart.fullname" . }}
+  labels:
+    {{- include "mychart.labels" . | nindent 4 }}
+spec:
+  type: {{ .Values.service.type }}
+  ports:
+    - port: {{ .Values.service.port }}
+      targetPort: http
+      protocol: TCP
+      name: http
+  selector:
+    {{- include "mychart.selectorLabels" . | nindent 4 }}

pkg/alpha.dagger.io/kubernetes/helm/tests/testdata/mychart/templates/serviceaccount.yaml

@@ -0,0 +1,12 @@
+{{- if .Values.serviceAccount.create -}}
+apiVersion: v1
+kind: ServiceAccount
+metadata:
+  name: {{ include "mychart.serviceAccountName" . }}
+  labels:
+    {{- include "mychart.labels" . | nindent 4 }}
+  {{- with .Values.serviceAccount.annotations }}
+  annotations:
+    {{- toYaml . | nindent 4 }}
+  {{- end }}
+{{- end -}}

pkg/alpha.dagger.io/kubernetes/helm/tests/testdata/mychart/templates/tests/test-connection.yaml

@@ -0,0 +1,15 @@
+apiVersion: v1
+kind: Pod
+metadata:
+  name: "{{ include "mychart.fullname" . }}-test-connection"
+  labels:
+    {{- include "mychart.labels" . | nindent 4 }}
+  annotations:
+    "helm.sh/hook": test-success
+spec:
+  containers:
+    - name: wget
+      image: busybox
+      command: ['wget']
+      args: ['{{ include "mychart.fullname" . }}:{{ .Values.service.port }}']
+  restartPolicy: Never

pkg/alpha.dagger.io/kubernetes/helm/tests/testdata/mychart/values.yaml

@@ -0,0 +1,68 @@
+# Default values for mychart.
+# This is a YAML-formatted file.
+# Declare variables to be passed into your templates.
+
+replicaCount: 1
+
+image:
+  repository: nginx
+  pullPolicy: IfNotPresent
+
+imagePullSecrets: []
+nameOverride: ""
+fullnameOverride: ""
+
+serviceAccount:
+  # Specifies whether a service account should be created
+  create: true
+  # Annotations to add to the service account
+  annotations: {}
+  # The name of the service account to use.
+  # If not set and create is true, a name is generated using the fullname template
+  name:
+
+podSecurityContext: {}
+  # fsGroup: 2000
+
+securityContext: {}
+  # capabilities:
+  #   drop:
+  #   - ALL
+  # readOnlyRootFilesystem: true
+  # runAsNonRoot: true
+  # runAsUser: 1000
+
+service:
+  type: ClusterIP
+  port: 80
+
+ingress:
+  enabled: false
+  annotations: {}
+    # kubernetes.io/ingress.class: nginx
+    # kubernetes.io/tls-acme: "true"
+  hosts:
+    - host: chart-example.local
+      paths: []
+  tls: []
+  #  - secretName: chart-example-tls
+  #    hosts:
+  #      - chart-example.local
+
+resources: {}
+  # We usually recommend not to specify default resources and to leave this as a conscious
+  # choice for the user. This also increases chances charts run on environments with little
+  # resources, such as Minikube. If you do want to specify resources, uncomment the following
+  # lines, adjust them as necessary, and remove the curly braces after 'resources:'.
+  # limits:
+  #   cpu: 100m
+  #   memory: 128Mi
+  # requests:
+  #   cpu: 100m
+  #   memory: 128Mi
+
+nodeSelector: {}
+
+tolerations: []
+
+affinity: {}

pkg/alpha.dagger.io/kubernetes/helm/tests/verify.cue

@@ -0,0 +1,51 @@
+package helm
+
+import (
+	"alpha.dagger.io/dagger/op"
+	"alpha.dagger.io/kubernetes"
+)
+
+#VerifyHelm: {
+	chartName: string
+
+	namespace: string
+
+	// Verify that pod exist
+	#getHelmPods:
+		"""
+        kubectl get pods --namespace "$KUBE_NAMESPACE" | grep "\(chartName)"
+    """
+
+	#up: [
+		op.#Load & {
+			from: kubernetes.#Kubectl
+		},
+
+		op.#WriteFile & {
+			dest:    "/getHelmPods.sh"
+			content: #getHelmPods
+		},
+
+		op.#WriteFile & {
+			dest:    "/kubeconfig"
+			content: TestKubeconfig
+			mode:    0o600
+		},
+
+		op.#Exec & {
+			always: true
+			args: [
+				"/bin/bash",
+				"--noprofile",
+				"--norc",
+				"-eo",
+				"pipefail",
+				"/getHelmPods.sh",
+			]
+			env: {
+				KUBECONFIG:     "/kubeconfig"
+				KUBE_NAMESPACE: namespace
+			}
+		},
+	]
+}

pkg/alpha.dagger.io/kubernetes/kubernetes.cue

@@ -0,0 +1,132 @@
+// Kubernetes client operations
+package kubernetes
+
+import (
+	"alpha.dagger.io/dagger/op"
+	"alpha.dagger.io/dagger"
+	"alpha.dagger.io/alpine"
+)
+
+// Kubectl client
+#Kubectl: {
+
+	// Kubectl version
+	version: dagger.#Input & {*"v1.19.9" | string}
+
+	#code: #"""
+		[ -e /usr/local/bin/kubectl ] || {
+			curl -sfL https://dl.k8s.io/${KUBECTL_VERSION}/bin/linux/amd64/kubectl -o /usr/local/bin/kubectl \
+			&& chmod +x /usr/local/bin/kubectl
+		}
+		"""#
+
+	#up: [
+		op.#Load & {
+			from: alpine.#Image & {
+				package: bash: true
+				package: jq:   true
+				package: curl: true
+			}
+		},
+		op.#WriteFile & {
+			dest:    "/entrypoint.sh"
+			content: #code
+		},
+		op.#Exec & {
+			args: [
+				"/bin/bash",
+				"--noprofile",
+				"--norc",
+				"-eo",
+				"pipefail",
+				"/entrypoint.sh",
+			]
+			env: KUBECTL_VERSION: version
+		},
+	]
+}
+
+// Apply Kubernetes resources
+#Resources: {
+
+	// Kubernetes config to deploy
+	source: dagger.#Input & {*null | dagger.#Artifact}
+
+	// Kubernetes manifest to deploy inlined in a string
+	manifest: dagger.#Input & {*null | string}
+
+	// Kubernetes manifest url to deploy remote configuration
+	url: dagger.#Input & {*null | string}
+
+	// Kubernetes Namespace to deploy to
+	namespace: dagger.#Input & {*"default" | string}
+
+	// Version of kubectl client
+	version: dagger.#Input & {*"v1.19.9" | string}
+
+	// Kube config file
+	kubeconfig: dagger.#Input & {string | dagger.#Secret}
+
+	#code: #"""
+		kubectl create namespace "$KUBE_NAMESPACE"  > /dev/null 2>&1 || true
+
+		if [ -d /source ] || [ -f /source ]; then
+			kubectl --namespace "$KUBE_NAMESPACE" apply -R -f /source
+			exit 0
+		fi
+
+		if [ -n "$DEPLOYMENT_URL" ]; then
+			kubectl --namespace "$KUBE_NAMESPACE" apply -R -f "$DEPLOYMENT_URL"
+			exit 0
+		fi
+		"""#
+
+	#up: [
+		op.#Load & {
+			from: #Kubectl & {"version": version}
+		},
+		op.#WriteFile & {
+			dest:    "/entrypoint.sh"
+			content: #code
+		},
+
+		if (kubeconfig & string) != _|_ {
+			op.#WriteFile & {
+				dest:    "/kubeconfig"
+				content: kubeconfig
+				mode:    0o600
+			}
+		},
+
+		if manifest != null {
+			op.#WriteFile & {
+				dest:    "/source"
+				content: manifest
+			}
+		},
+		op.#Exec & {
+			always: true
+			args: [
+				"/bin/bash",
+				"--noprofile",
+				"--norc",
+				"-eo",
+				"pipefail",
+				"/entrypoint.sh",
+			]
+			env: {
+				KUBECONFIG:     "/kubeconfig"
+				KUBE_NAMESPACE: namespace
+				if url != null {
+					DEPLOYMENT_URL: url
+				}
+			}
+			if manifest == null && source != null {
+				mount: "/source": from: source
+			}
+			if (kubeconfig & dagger.#Secret) != _|_ {
+				mount: "/kubeconfig": secret: kubeconfig
+			}
+		},
+	]
+}

pkg/alpha.dagger.io/kubernetes/kustomize/kustomization.cue

@@ -0,0 +1,99 @@
+// Kustomize config management
+package kustomize
+
+import (
+	"alpha.dagger.io/dagger/op"
+	"alpha.dagger.io/dagger"
+	"alpha.dagger.io/alpine"
+)
+
+#Kustomization: {
+	// Kustomize binary version
+	version: *"v3.8.7" | string @dagger(input)
+
+	#code: #"""
+		[ -e /usr/local/bin/kubectl ] || {
+			curl -s "https://raw.githubusercontent.com/kubernetes-sigs/kustomize/master/hack/install_kustomize.sh" | bash && mv kustomize /usr/local/bin
+		}
+		"""#
+
+	#up: [
+		op.#Load & {
+			from: alpine.#Image & {
+				package: bash: true
+				package: jq:   true
+				package: curl: true
+			}
+		},
+
+		op.#WriteFile & {
+			dest:    "/entrypoint.sh"
+			content: #code
+		},
+
+		op.#Exec & {
+			args: [
+				"/bin/bash",
+				"--noprofile",
+				"--norc",
+				"-eo",
+				"pipefail",
+				"/entrypoint.sh",
+			]
+		},
+	]
+}
+
+// Apply a Kubernetes Kustomize folder
+#Kustomize: {
+	// Kubernetes source
+	source: dagger.#Artifact @dagger(input)
+
+	// Optional Kustomization file
+	kustomization: string @dagger(input)
+
+	// Kustomize binary version
+	version: *"v3.8.7" | string @dagger(input)
+
+	#code: #"""
+		cp /kustomization.yaml /source | true
+		mkdir -p /output
+		kustomize build /source >> /output/result.yaml
+		"""#
+
+	#up: [
+		op.#Load & {
+			from: #Kustomization & {"version": version}
+		},
+
+		op.#WriteFile & {
+			dest:    "/entrypoint.sh"
+			content: #code
+		},
+
+		if kustomization != _|_ {
+			op.#WriteFile & {
+				dest:    "/kustomization.yaml"
+				content: kustomization
+				mode:    0o600
+			}
+		},
+
+		op.#Exec & {
+			always: true
+			args: [
+				"/bin/bash",
+				"--noprofile",
+				"--norc",
+				"-eo",
+				"pipefail",
+				"/entrypoint.sh",
+			]
+			mount: "/source": from: source
+		},
+
+		op.#Subdir & {
+			dir: "/output"
+		},
+	]
+}

pkg/alpha.dagger.io/kubernetes/kustomize/tests/kustomize.cue

@@ -0,0 +1,31 @@
+package kustomize
+
+import (
+	"encoding/yaml"
+	"alpha.dagger.io/dagger"
+)
+
+TestKustomize: {
+	testdata: dagger.#Artifact
+
+	// Run Kustomize
+	kustom: #Kustomize & {
+		source:        testdata
+		kustomization: yaml.Marshal({
+			resources: ["deployment.yaml", "pod.yaml"]
+			images: [{
+				name:   "nginx"
+				newTag: "v1"
+			}]
+			replicas: [{
+				name:  "nginx-deployment"
+				count: 2
+			}]
+		})
+	}
+
+	// Verify kustomization generation
+	verify: #VerifyKustomize & {
+		source: kustom
+	}
+}

pkg/alpha.dagger.io/kubernetes/kustomize/tests/testdata/deployment.yaml

@@ -0,0 +1,22 @@
+apiVersion: apps/v1
+kind: Deployment
+metadata:
+  name: nginx-deployment
+  labels:
+    app: nginx-deployment
+spec:
+  replicas: 1
+  template:
+    metadata:
+      name: nginx-deployment
+      labels:
+        app: nginx-deployment
+    spec:
+      containers:
+        - name: nginx-deployment
+          image: nginx
+          imagePullPolicy: IfNotPresent
+      restartPolicy: Always
+  selector:
+    matchLabels:
+      app: nginx-deployment

pkg/alpha.dagger.io/kubernetes/kustomize/tests/testdata/pod.yaml

@@ -0,0 +1,12 @@
+apiVersion: v1
+kind: Pod
+metadata:
+  name: test-pod
+  labels:
+    app: test-pod
+spec:
+  containers:
+    - name: test-pod
+      image: nginx
+      imagePullPolicy: IfNotPresent
+  restartPolicy: Always

pkg/alpha.dagger.io/kubernetes/kustomize/tests/verify.cue

@@ -0,0 +1,72 @@
+package kustomize
+
+import (
+	"alpha.dagger.io/dagger/op"
+	"alpha.dagger.io/dagger"
+	"alpha.dagger.io/alpine"
+)
+
+#VerifyKustomize: {
+	source: dagger.#Artifact
+
+	#up: [
+		op.#Load & {
+			from: alpine.#Image & {
+				package: bash: true
+			}
+		},
+
+		// Check files
+		op.#Exec & {
+			always: true
+			args: [
+				"sh", "-c", "test $(ls /source | wc -l) = 1",
+			]
+			mount: "/source": from: source
+		},
+
+		// Check image tag kustomization
+		op.#Exec & {
+			always: true
+			args: [
+				"sh", "-c", #"""
+						grep -q "\- image: nginx:v1" /source/result.yaml
+					"""#,
+			]
+			mount: "/source": from: source
+		},
+
+		// Check replicas kustomization
+		op.#Exec & {
+			always: true
+			args: [
+				"sh", "-c", #"""
+						grep -q "replicas: 2" /source/result.yaml
+					"""#,
+			]
+			mount: "/source": from: source
+		},
+
+		// Check pod merge by kustomization
+		op.#Exec & {
+			always: true
+			args: [
+				"sh", "-c", #"""
+						grep -q "kind: Pod" /source/result.yaml
+					"""#,
+			]
+			mount: "/source": from: source
+		},
+
+		// Check pod name
+		op.#Exec & {
+			always: true
+			args: [
+				"sh", "-c", #"""
+						grep -q "name: test-pod" /source/result.yaml
+					"""#,
+			]
+			mount: "/source": from: source
+		},
+	]
+}

pkg/alpha.dagger.io/kubernetes/tests/kubernetes.cue

@@ -0,0 +1,61 @@
+package kubernetes
+
+import (
+	"encoding/yaml"
+	"alpha.dagger.io/random"
+)
+
+// We assume that a kinD cluster is running locally
+// To deploy a local KinD cluster, follow this link : https://kind.sigs.k8s.io/docs/user/quick-start/
+TestKubeconfig: string @dagger(input)
+
+TestKubeApply: {
+	suffix: random.#String & {
+		seed: ""
+	}
+
+	// Pod spec
+	kubeSrc: {
+		apiVersion: "v1"
+		kind:       "Pod"
+		metadata: name: "kube-test-\(suffix.out)"
+		spec: {
+			restartPolicy: "Never"
+			containers: [{
+				name:  "test"
+				image: "hello-world"
+			}]
+		}
+	}
+
+	// Apply deployment
+	resources: #Resources & {
+		kubeconfig: TestKubeconfig
+		namespace:  "dagger-test"
+		manifest:   yaml.Marshal(kubeSrc)
+	}
+
+	// Verify deployment
+	verify: #VerifyApply & {
+		podname:   kubeSrc.metadata.name
+		namespace: resources.namespace
+	}
+}
+
+TestLinkApply: {
+	// Podname from hello-world-pod
+	_podname: "hello-world"
+
+	// Apply deployment
+	resources: #Resources & {
+		kubeconfig: TestKubeconfig
+		namespace:  "dagger-test"
+		url:        "https://gist.githubusercontent.com/grouville/04402633618f3289a633f652e9e4412c/raw/293fa6197b78ba3fad7200fa74b52c62ec8e6703/hello-world-pod.yaml"
+	}
+
+	// Verify deployment
+	verify: #VerifyApply & {
+		podname:   _podname
+		namespace: resources.namespace
+	}
+}

pkg/alpha.dagger.io/kubernetes/tests/verify.cue

@@ -0,0 +1,78 @@
+package kubernetes
+
+import (
+	"alpha.dagger.io/dagger/op"
+)
+
+#VerifyApply: {
+	podname: string
+
+	namespace: string
+
+	// Verify that pod exist
+	#GetPods:
+		"""
+        kubectl get pods --namespace "$KUBE_NAMESPACE" \( podname )
+    """
+
+	// Clear that pod for future test
+	#DeletePods:
+		"""
+        kubectl delete pods --namespace "$KUBE_NAMESPACE" \( podname )
+    """
+
+	#up: [
+		op.#Load & {
+			from: #Kubectl
+		},
+
+		op.#WriteFile & {
+			dest:    "/kubeconfig"
+			content: TestKubeconfig
+			mode:    0o600
+		},
+
+		op.#WriteFile & {
+			dest:    "/getPods.sh"
+			content: #GetPods
+		},
+
+		// Check pods
+		op.#Exec & {
+			always: true
+			args: [
+				"/bin/bash",
+				"--noprofile",
+				"--norc",
+				"-eo",
+				"pipefail",
+				"/getPods.sh",
+			]
+			env: {
+				KUBECONFIG:     "/kubeconfig"
+				KUBE_NAMESPACE: namespace
+			}
+		},
+
+		op.#WriteFile & {
+			dest:    "/deletePods.sh"
+			content: #DeletePods
+		},
+
+		op.#Exec & {
+			always: true
+			args: [
+				"/bin/bash",
+				"--noprofile",
+				"--norc",
+				"-eo",
+				"pipefail",
+				"/deletePods.sh",
+			]
+			env: {
+				KUBECONFIG:     "/kubeconfig"
+				KUBE_NAMESPACE: namespace
+			}
+		},
+	]
+}