cue modules: move stdlib to pkg/alpha.dagger.io

In preparation for Europa, we will vendor multiple CUE modules:

- `pkg/alpha.dagger.io`: legacy non-europa packages
- `pkg/dagger.io`: core Europa packages
- `pkg/universe.dagger.io`: Europa universe

Signed-off-by: Andrea Luzzardi <aluzzardi@gmail.com>

pkg/alpha.dagger.io/aws/s3/s3.cue

@@ -0,0 +1,98 @@
+// AWS Simple Storage Service
+package s3
+
+import (
+	"alpha.dagger.io/dagger"
+	"alpha.dagger.io/dagger/op"
+	"alpha.dagger.io/aws"
+)
+
+// S3 Bucket object(s) sync
+#Object: {
+
+	// AWS Config
+	config: aws.#Config
+
+	// Source Artifact to upload to S3
+	source: dagger.#Artifact @dagger(input)
+
+	// Target S3 URL (eg. s3://<bucket-name>/<path>/<sub-path>)
+	target: string @dagger(input)
+
+	// Delete files that already exist on remote destination
+	delete: *false | true @dagger(input)
+
+	// Object content type
+	contentType: string | *"" @dagger(input)
+
+	// Always write the object to S3
+	always: *true | false @dagger(input)
+
+	// Upload method
+	uploadMethod: *"cp" | "sync"
+
+	// URL of the uploaded S3 object
+	url: {
+		string
+
+		#up: [
+			op.#Load & {
+				from: aws.#CLI & {
+					"config": config
+				}
+			},
+
+			op.#Exec & {
+				if always {
+					always: true
+				}
+				env: {
+					TARGET:           target
+					OPT_CONTENT_TYPE: contentType
+					if delete {
+						OPT_DELETE: "1"
+					}
+					UPLOAD_METHOD: uploadMethod
+				}
+
+				mount: "/source": from: source
+
+				args: [
+					"/bin/bash",
+					"--noprofile",
+					"--norc",
+					"-eo",
+					"pipefail",
+					"-c",
+					#"""
+						opts=()
+						case "$UPLOAD_METHOD" in
+							sync)
+								[ -n "$OPT_DELETE" ] && opts+="--delete"
+								opts+="--exact-timestamps"
+								;;
+							cp)
+								opts+="--recursive"
+								;;
+							*)
+								echo "not supported command"
+								exit 1
+								;;
+						esac
+						[ -n "$OPT_CONTENT_TYPE" ] && opts+="--content-type $OPT_CONTENT_TYPE"
+						[ -n "$OPT_DELETE" ] && opts+="--delete"
+						aws s3 "$UPLOAD_METHOD" ${opts[@]} /source "$TARGET"
+						echo -n "$TARGET" \
+							| sed -E 's=^s3://([^/]*)/=https://\1.s3.amazonaws.com/=' \
+							> /url
+						"""#,
+				]
+			},
+
+			op.#Export & {
+				source: "/url"
+				format: "string"
+			},
+		]
+	} @dagger(output)
+}

pkg/alpha.dagger.io/aws/s3/tests/s3.cue

@@ -0,0 +1,46 @@
+package s3
+
+import (
+	"alpha.dagger.io/dagger"
+	"alpha.dagger.io/aws"
+	"alpha.dagger.io/random"
+)
+
+TestConfig: awsConfig: aws.#Config & {
+	region: "us-east-2"
+}
+
+bucket: "dagger-ci"
+
+content: "A simple test sentence"
+
+TestDirectory: dagger.#Artifact
+
+TestS3Object: {
+	suffix: random.#String & {
+		seed: "s3"
+	}
+
+	target: "s3://\(bucket)/\(suffix.out)/"
+
+	deploy: #Object & {
+		always:   true
+		config:   TestConfig.awsConfig
+		source:   TestDirectory
+		"target": target
+	}
+
+	verifyFile: #VerifyS3 & {
+		config: TestConfig.awsConfig
+		target: deploy.target
+		url:    deploy.url
+		file:   "dirFile.txt"
+	}
+
+	verifyDir: #VerifyS3 & {
+		config: TestConfig.awsConfig
+		target: deploy.target
+		url:    deploy.url
+		file:   "foo.txt"
+	}
+}

pkg/alpha.dagger.io/aws/s3/tests/testdata/bar/foo.txt

@@ -0,0 +1 @@
+Test recursivity

pkg/alpha.dagger.io/aws/s3/tests/testdata/dirFile.txt

@@ -0,0 +1 @@
+Test directory

pkg/alpha.dagger.io/aws/s3/tests/verify.cue

@@ -0,0 +1,89 @@
+package s3
+
+import (
+	"alpha.dagger.io/aws"
+	"alpha.dagger.io/alpine"
+	"alpha.dagger.io/dagger/op"
+)
+
+#List: {
+	// AWS Config
+	config: aws.#Config
+
+	// Target S3 URL (e.g. s3://<bucket-name>/<path>/<sub-path>)
+	target: string
+
+	// URL: dummy URL, used to force a dependency
+	url: string
+
+	contents: {
+		string
+
+		#up: [
+			op.#Load & {
+				from: aws.#CLI & {
+					"config": config
+				}
+			},
+
+			op.#Exec & {
+				args: [
+					"/bin/bash",
+					"--noprofile",
+					"--norc",
+					"-eo",
+					"pipefail",
+					"-c",
+					#"""
+					aws s3 ls --recursive \#(target) > /contents
+					"""#,
+				]
+				env: URL: url
+			},
+
+			op.#Export & {
+				source: "/contents"
+				format: "string"
+			},
+		]
+	}
+}
+
+#VerifyS3: {
+	file:   string
+	config: aws.#Config
+	target: string
+	url:    string
+
+	lists: #List & {
+		"config": config
+		"target": target
+		"url":    url
+	}
+
+	test: #up: [
+		op.#Load & {
+			from: alpine.#Image & {
+				package: bash: true
+			}
+		},
+
+		op.#WriteFile & {
+			dest:    "/test"
+			content: lists.contents
+		},
+
+		op.#Exec & {
+			always: true
+			args: [
+				"/bin/bash",
+				"--noprofile",
+				"--norc",
+				"-eo",
+				"pipefail",
+				"-c",
+				"grep -q \(file) /test",
+			]
+		},
+	]
+}