Add docker cli package

Signed-off-by: Helder Correia <174525+helderco@users.noreply.github.com>

pkg/universe.dagger.io/docker/cli/client.cue

@@ -0,0 +1,84 @@
+package cli
+
+import (
+	"dagger.io/dagger"
+	"universe.dagger.io/docker"
+)
+
+// See https://github.com/dagger/dagger/issues/1856
+
+// Run a docker CLI command
+#Run: {
+	#RunSocket | #RunSSH | #RunTCP
+
+	_image: docker.#Pull & {
+		source: "docker:20.10.13-alpine3.15"
+	}
+
+	input: _image.output
+}
+
+// Connect via local docker socket
+#RunSocket: {
+	host: dagger.#Service
+
+	docker.#Run & {
+		mounts: docker: {
+			dest:     "/var/run/docker.sock"
+			contents: host
+		}
+	}
+}
+
+// Connect via SSH
+#RunSSH: {
+	host: =~"^ssh://.+"
+
+	ssh: {
+		// Private SSH key
+		key?: dagger.#Secret
+
+		// Known hosts file contents
+		knownHosts?: dagger.#Secret
+
+		// FIXME: implement keyPassphrase
+	}
+
+	docker.#Run & {
+		env: DOCKER_HOST: host
+
+		if ssh.key != _|_ {
+			mounts: ssh_key: {
+				dest:     "/root/.ssh/id_rsa"
+				contents: ssh.key
+			}
+		}
+
+		if ssh.knownHosts != _|_ {
+			mounts: ssh_hosts: {
+				dest:     "/root/.ssh/known_hosts"
+				contents: ssh.knownHosts
+			}
+		}
+	}
+}
+
+// Connect via HTTP/HTTPS
+#RunTCP: {
+	host: =~"^tcp://.+"
+
+	docker.#Run & {
+		env: DOCKER_HOST: host
+
+		// Directory with certificates to verify ({ca,cert,key}.pem files).
+		// This enables HTTPS.
+		certs?: dagger.#FS
+
+		if certs != _|_ {
+			mounts: "certs": {
+				dest:     "/certs/client"
+				contents: certs
+			}
+		}
+	}
+}

pkg/universe.dagger.io/docker/cli/load.cue

@@ -0,0 +1,38 @@
+package cli
+
+import (
+	"dagger.io/dagger"
+	"universe.dagger.io/docker"
+)
+
+// Load an image into a docker daemon
+#Load: {
+	// Image to load
+	image: docker.#Image
+
+	// Name and optionally a tag in the 'name:tag' format
+	tag: docker.#Ref
+
+	// Exported image ID
+	imageID: _export.imageID
+
+	// Root filesystem with exported file
+	result: _export.output
+
+	_export: dagger.#Export & {
+		"tag":  tag
+		input:  image.rootfs
+		config: image.config
+	}
+
+	#Run & {
+		mounts: src: {
+			dest:     "/src"
+			contents: _export.output
+		}
+		command: {
+			name: "load"
+			flags: "-i": "/src/image.tar"
+		}
+	}
+}

pkg/universe.dagger.io/docker/cli/test/load.cue

@@ -0,0 +1,55 @@
+package test
+
+import (
+	"dagger.io/dagger"
+
+	"universe.dagger.io/alpine"
+	"universe.dagger.io/bash"
+	"universe.dagger.io/docker"
+	"universe.dagger.io/docker/cli"
+)
+
+dagger.#Plan & {
+	client: filesystem: "/var/run/docker.sock": read: contents: dagger.#Service
+
+	actions: test: {
+		_cli: alpine.#Build & {
+			packages: {
+				bash: {}
+				"docker-cli": {}
+			}
+		}
+
+		_image: docker.#Run & {
+			input: _cli.output
+			command: {
+				name: "touch"
+				args: ["/foo.bar"]
+			}
+		}
+
+		load: cli.#Load & {
+			image: _image.output
+			host:  client.filesystem."/var/run/docker.sock".read.contents
+			tag:   "dagger:load"
+		}
+
+		verify: bash.#Run & {
+			input: _cli.output
+			mounts: docker: {
+				contents: client.filesystem."/var/run/docker.sock".read.contents
+				dest:     "/var/run/docker.sock"
+			}
+			env: {
+				IMAGE_NAME: load.tag
+				IMAGE_ID:   load.imageID
+				// FIXME: without this forced dependency, load.command might not run
+				DEP: "\(load.success)"
+			}
+			script: contents: #"""
+				test "$(docker image inspect $IMAGE_NAME -f '{{.Id}}')" = "$IMAGE_ID"
+				docker run --rm $IMAGE_NAME stat /foo.bar
+				"""#
+		}
+	}
+}

pkg/universe.dagger.io/docker/cli/test/run.cue

@@ -0,0 +1,39 @@
+package test
+
+import (
+	"dagger.io/dagger"
+
+	"universe.dagger.io/alpine"
+	"universe.dagger.io/docker/cli"
+)
+
+dagger.#Plan & {
+	client: filesystem: "/var/run/docker.sock": read: contents: dagger.#Service
+
+	actions: test: {
+		run: cli.#Run & {
+			host: client.filesystem."/var/run/docker.sock".read.contents
+			command: name: "info"
+		}
+
+		differentImage: {
+			_cli: alpine.#Build & {
+				packages: {
+					bash: {}
+					"docker-cli": {}
+				}
+			}
+			run: cli.#RunSocket & {
+				input: _cli.output
+				host:  client.filesystem."/var/run/docker.sock".read.contents
+				command: {
+					name: "docker"
+					args: ["info"]
+				}
+			}
+		}
+
+		// FIXME: test remote connections with `docker:dind` image
+		// when we have long running tasks
+	}
+}

pkg/universe.dagger.io/docker/cli/test/test.bats

@@ -0,0 +1,10 @@
+setup() {
+    load '../../../bats_helpers'
+
+    common_setup
+}
+
+@test "docker/cli" {
+    dagger "do" -p ./run.cue test
+    dagger "do" -p ./load.cue test
+}